{
  inputs,
  system,
  ...
}:
with inputs;
  final: prev: {
    ## My Packages ##
    webone = prev.pkgs.callPackage ./packages/webone {}; # WebOne HTTP proxy.
    cups-dymo = prev.pkgs.callPackage ./packages/cups-dymo {}; # Dymo label printer drivers.

    ## Package Mods ##
    # Custom build of iosevka
    iosevka = prev.iosevka.override {
      set = "Custom";

      privateBuildPlan = {
        family = "IosevkaCustom";
        spacing = "term";
        serifs = "sans";
        noCvSs = false;
        exportGlyphNames = true;
        variants.inherits = "ss05";

        weights = {
          Regular = {
            shape = 400;
            menu = 400;
            css = 400;
          };
          Bold = {
            shape = 700;
            menu = 700;
            css = 700;
          };
        };
      };
    };

    # PrismLauncher with Temurin JRE;
    prismlauncher = prev.prismlauncher.override {
      jdks = [
        prev.pkgs.temurin-jre-bin
      ];
    };

    # Phinger cursors (everforest version).
    phinger-cursors-everforest = prev.phinger-cursors.overrideAttrs (prevAttrs: rec {
      pname = "phinger-cursors-everforest";
      version = "3212590527";

      src = prev.fetchurl {
        url = "https://github.com/talwat/everforest-cursors/releases/download/${version}/everforest-cursors-variants.tar.bz2";
        sha256 = "sha256-xXgtN9wbjbrGLUGYymMEGug9xEs9y44mq18yZVdbiuU=";
      };

      installPhase = ''
        runHook preInstall
        mkdir -p $out/share/icons
        cp -r ./everforest-cursors* $out/share/icons
        runHook postInstall
      '';
    });

    # Latest Feishin.
    feishin =
      (import nixpkgs-pr-feishin {
        inherit system;
        overlays = [
          (final: prev: {
            feishin = prev.feishin.overrideAttrs (prevAttrs: rec {
              pname = "feishin";
              version = "0.19.0";

              src = prev.fetchFromGitHub {
                owner = "jeffvli";
                repo = "feishin";
                rev = "v${version}";
                hash = "sha256-2Jry/wulzkS1P4tughDlH5klqNngPNmFuC5Nqe9sakM=";
              };

              pnpmDeps = prev.pnpm_10.fetchDeps {
                inherit pname version src;
                hash = "sha256-4cbrK+3nFD2NgoaGoAQdQ0+/07WiUiFUAyJFOsge8X8=";
              };
            });
          })
        ];
      }).feishin;

    ## Unstable Channel ##
    protonmail-desktop = (import nixpkgs-unstable {inherit system;}).protonmail-desktop; # Latest protonmail-desktop

    # Latest FluffyChat.
    fluffychat =
      (import nixpkgs-unstable
        {
          inherit system;
          overlays = [
            (final: prev: {
              fluffychat = prev.fluffychat.overrideAttrs (prevAttrs: {
                desktopItems = [
                  ((builtins.elemAt prevAttrs.desktopItems 0).override {startupWMClass = "fluffychat";})
                ];
              });
            })
          ];
        }).fluffychat;
  }